home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / yase.arc / EDIT4.ASM < prev    next >
Assembly Source File  |  1986-12-13  |  5KB  |  151 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. *****************************************************************
  13. * Editor Auxiliary Functions
  14.  
  15.     xref    cmd_w,lineed,printf,to_end,write_out
  16.     xdef    prompt,dirty,ask,eof,cnt_nl,seek,chk_blk,default
  17.     xdef    putfile
  18.  
  19. #edit.h
  20.  
  21. *****************************************************************
  22. * EOF - moves cursor to end of file
  23. eof:
  24.     bsr    to_end        * move everything before cursor
  25.     bsr    cnt_nl        * count newlines behind cursor
  26.     rts
  27. *****************************************************************
  28. * CNT_NL - count newlines behind cursor
  29. cnt_nl:
  30.     move.l    b_buf(a5),a0    * a0 is search start address
  31.     move.l    b_gap(a5),d0    * compute number of bytes
  32.     sub.l    a0,d0        * d0 is number of file bytes
  33.     clr.w    d1        * d1 is newline counter
  34.     move.b    #10,d2        * do register compare - faster
  35.     bra    sk0_nl        * loop test before loop body
  36. lp0_nl:
  37.     cmp.b    (a0)+,d2    * look for newline
  38.     bne    sk0_nl        * nope.
  39.     addq.w    #1,d1        * increment line counter
  40. sk0_nl:
  41.     dbra    d0,lp0_nl    * loop test
  42.     move.w    d1,log_lin(a5)    * save new logical line count
  43.     rts
  44. *****************************************************************
  45. * DIRTY - marks file as modified, and clears block markers
  46. dirty:
  47.     clr.l    blk_st(a5)    * reset block start marker
  48.     clr.l    blk_end(a5)    * reset block end marker
  49.     move.w    #-1,modify(a5)    * set file modified flag
  50.     rts
  51. *****************************************************************
  52. * SEEK - moves the cursor to the location in d0
  53. seek:
  54.     move.l    b_gap(a5),a0    * gap start address in A0
  55.     move.l    e_gap(a5),a1    * gap end location in A1
  56.     sub.l    a0,d0        * calculate characters to dest.
  57.     bgt    sk1_sk        * move towards end of file
  58.     neg.w    d0        * take abs() of char count
  59.     bra    sk2_sk        * loop test before branch
  60. lp0_sk:
  61.     move.b    -(a0),-(a1)    * move towards start of file
  62. sk2_sk:
  63.     dbra    d0,lp0_sk    * to start of file loop
  64.     bra    sk0_sk        * get out
  65. lp1_sk:
  66.     move.b    (a1)+,(a0)+    * move towards end of file
  67. sk1_sk:
  68.     dbra    d0,lp1_sk    * to end of file loop
  69. sk0_sk:
  70.     move.l    a0,b_gap(a5)    * reset gap start address
  71.     move.l    a1,e_gap(a5)    * reset gap end address
  72.     rts
  73. *****************************************************************
  74. * CHK_BLK - checks for valid block markers
  75. chk_blk:
  76.     tst.l    blk_st(a5)    * check if start is marked
  77.     beq    sk0_cb        * branch if not
  78.     tst.l    blk_end(a5)    * check if end is marked
  79.     beq    sk1_cb        * branch if not
  80.     move.l    blk_end(a5),d0    * check if end is after start
  81.     cmp.l    blk_st(a5),d0    
  82.     ble    sk3_cb        * branch if mismarked
  83.     clr.w    d0        * get "ok" return code
  84.     bra    sk2_cb        * branch out
  85. sk0_cb:
  86.     move.w    #7,ed_err(a5)    * show start not marked error
  87.     bra    sk2_cb
  88. sk1_cb:
  89.     move.w    #8,ed_err(a5)    * show end not marked error
  90.     bra    sk2_cb
  91. sk3_cb:
  92.     move.w    #9,ed_err(a5)    * show mismark error
  93. sk2_cb:
  94.     rts
  95. *****************************************************************
  96. * DEFAULT: User hits unspecified subcommand key
  97. default:
  98.     rts
  99. *****************************************************************
  100. * PUTFILE - puts the file to disk - returns D0 nonzero on error
  101. putfile:
  102.     bsr    to_end        * move all text behind cursor
  103.     lea    fname(a5),a0    * load name for file write
  104.     move.l    b_buf(a5),a1    * start of data to write
  105.     move.l    b_gap(a5),d1    * calculate number of bytes
  106.     sub.l    a1,d1        * D1 is numbers of bytes to write
  107.     bsr    write_out    * write the file to disk
  108.     tst.w    d0        * check return code
  109.     beq    sk0_pf        * skip error message with no err
  110.     move.w    #3,ed_err(a5)    * load edit error code
  111. sk0_pf:
  112.     rts
  113. *****************************************************************
  114. * PROMPT - outputs a prompt in command window. A0 points to prmt
  115. prompt:
  116.     move.l    a0,-(a7)    * push parameter string address
  117.     move.l    #cmd_w,a0    * get command window address
  118.     move.w    w_ulcy(a0),-(a7)  push Y screen address
  119.     move.w    w_ulcx(a0),-(a7)  push X screen address
  120.     move.l    #p_str,-(a7)    * push format string address
  121.     bsr    printf        * output prompt
  122.     addq.l    #8,a7        * adjust stack
  123.     move.l    (a7)+,a0    * restore a0
  124.     rts
  125. p_str:    dc.b    '%v%-78s',0
  126.     dc.w    0
  127. *****************************************************************
  128. * ASK - prompts human for string input - A0 is prompt string,
  129. *    A1 is input string
  130. ask:
  131.     bsr    prompt        * output prompt string
  132.     move.l    #cmd_w,a2    * a2 has output limits
  133.     move.w    w_ulcx(a2),d0    * d0 will count be X offset
  134. lp0_ask:
  135.     tst.b    (a0)+        * see if we have a null
  136.     beq    sk0_ask        * jump out if null
  137.     addq.w    #1,d0        * increment X position
  138.     bra    lp0_ask        * loop again for strlen
  139. sk0_ask:
  140.     move.w    w_lrcx(a2),d1    * d1 is input window right edge
  141.     sub.w    d0,d1        * d1 is now max chars in input
  142.     move.w    d1,-(a7)    * push max number for lineed
  143.     move.w    d0,-(a7)    * push screen column
  144.     move.w    w_ulcy(a2),-(a7)  push screen line
  145.     move.l    a1,-(a7)    * push input string address
  146.     bsr    lineed        * go edit input line
  147.     add.l    #10,a7        * adjust stack
  148.     rts
  149.  
  150.     end
  151.